///////////////////////////////////////////////////////////////////////////////////////
//			     	                 				     //
// PoD-Cash:		v1.0 	           	 				     //
// Written by:		*PoD[BoT] aka SpeedFreak 				     //
// Date written:	09.11.2010               				     //
// Last Update:		10.11.2010               				     //
//			                         				     //
// Description:				         				     //
// Set cash on round start.			 				     //
//										     //
// Installation:								     //
// 1: Edit "config.cfg" and move the pod_cash folder to: cstrike/addons/eventscripts //
// 2: Upload scriptdate folder to: cstrike/addons/eventscripts			     //
// 3: Add "es_load scriptdate" and "es_load pod_cash" to your autoexec.cfg 	     //
// 4: Restart your server.			  				     //
// 						 				     //
// Special thanks to:						 		     //
// .:MiB:. - Because of your auto-update script ;)				     //
// 						 				     //
// www.CssGermanTutorials.de			 				     //
// www.Counterstrike-Tutorials.de		 				     //
// http://forums.eventscripts.com						     //
//						 				     //
///////////////////////////////////////////////////////////////////////////////////////

block load
{
	es_xset pod_cash_version v1.0
 	es_makepublic pod_cash_version

	es_xset cash_amount 16000
	es_xset cash_interval 1
	es_xset cash_filter_bots 0
	es_xset cash_filter_team 0
	es_xset cash_filter_steam 0
	es_xset cash_first_round 0
	es_xset cash_advert 1
	es_xset cash_advert_delay 120
	es_xset cash_update 2 

	es_xmexec ../addons/eventscripts/pod_cash/config.cfg
	es_xdoblock pod_cash/debugvars
	es_xdoblock pod_cash/setvars
	if (server_var(cash_filter_steam) == 1) do
	{
		keygroupremove pod_cash
		es_keygroupload pod_cash |pod_cash
	}
	es_xset temptext1 0
	es_format temptext1 "Each %1 Rounds!" server_var(cash_interval)
	if (server_var(cash_interval) == 1) then es_xset temptext1 "Each Round!"
	es_xset temptext2 "Everyone"
	if (server_var(cash_filter_team) == 1) then es_xset temptext2 Terrorists
	if (server_var(cash_filter_team) == 2) then es_xset temptext2 Counter-Terrorists
	if (server_var(cash_filter_steam) == 1) then es_xset temptext2 Admins
	if (server_var(cash_advert) == 2) then es_delayed server_var(cash_advert_delay) es_xdoblock pod_cash/advert
	if (server_var(cash_advert) == 3) then es_delayed server_var(cash_advert_delay) es_xdoblock pod_cash/advert
	if (server_var(cash_update) == 1) then scriptdate_add_list "pod_cash" "pod_cash_version" "0" "www.nextgenerationgaming.de/addons/pod_cash"
	if (server_var(cash_update) == 2) then scriptdate_add_list "pod_cash" "pod_cash_version" "1" "www.nextgenerationgaming.de/addons/pod_cash"

	es_msg #multi #green[PoD-Cash]#lightgreen server_var(pod_cash_version) #default- Loaded!
	es_msg #multi #green[PoD-Cash]#lightgreen server_var(temptext2) #defaultwill receive#lightgreen server_var(cash_amount) #defaultCash#lightgreen server_var(temptext1)
}

block unload
{
	if (server_var(cash_filter_steam) == 1) then keygroupremove pod_cash
	if (server_var(cash_update) == 1) then scriptdate_remove_list "pod_cash"
	if (server_var(cash_update) == 2) then scriptdate_remove_list "pod_cash"

	es_msg #multi #green[PoD-Cash]#lightgreen server_var(pod_cash_version) #default- Unloaded!
}

block setvars
{
	es_xset cash_werbung_aktiviert 0
	es_xset cash_1st_played 0
	es_xset cash_interval_current 0
	if (server_var(cash_first_round) == 0) then es_xset cash_1st_played 1
}

block debugvars
{
	if (server_var(cash_amount) < 1) then es_xset cash_amount 1
	if (server_var(cash_amount) > 16000) then es_xset cash_amount 16000
	if (server_var(cash_interval) < 1) then es_xset cash_interval 1
	if (server_var(cash_advert_delay) < 1) then es_xset cash_advert_delay 1
}

block advert
{
	if (server_var(cash_advert) == 2) then es_delayed server_var(cash_advert_delay) es_xdoblock pod_cash/advert
	if (server_var(cash_advert) == 3) then es_delayed server_var(cash_advert_delay) es_xdoblock pod_cash/advert
	es_msg #multi #green[PoD-Cash]#lightgreen server_var(temptext2) #defaultwill receive#lightgreen server_var(cash_amount) #defaultCash#lightgreen server_var(temptext1)
}

event es_map_start
{
	if (server_var(cash_advert) == 2) then es_delayed server_var(cash_advert_delay) es_xdoblock pod_cash/advert
	if (server_var(cash_advert) == 3) then es_delayed server_var(cash_advert_delay) es_xdoblock pod_cash/advert
}

event player_spawn
{
	es_xset cash_cancel 0
	if (server_var(cash_1st_played) == 1) do
	{
		if (server_var(cash_interval_current) == server_var(cash_interval)) do
		{
			es_set user event_var(userid)
			//Bot-Check
			if (server_var(cash_filter_bots) == 0) do
			{
				es_xdoblock pod_cash/filter_bot
				if (server_var(check_bot) == 1) then es_xset cash_cancel 1
				//if (server_var(check_bot) == 1) then es_xmsg #green Cancel: Bot
			}

			//SteamID-Check
			if (server_var(cash_filter_steam) == 1) do
			{
				es_xdoblock pod_cash/filter_steam
				if (server_var(check_steam) == 0) then es_xset cash_cancel 1
				//if (server_var(check_steam) == 0) then es_xmsg #green Cancel: Steam-ID
			}

			//Team-Check
			if (server_var(cash_filter_team) == 1) do
			{
				es_xdoblock pod_cash/filter_team
				if (server_var(check_team) != 2) then es_xset cash_cancel 1
				//if (server_var(check_team) != 2) then es_xmsg #green Cancel: Team
			}
			if (server_var(cash_filter_team) == 2) do
			{
				es_xdoblock pod_cash/filter_team
				if (server_var(check_team) != 3) then es_xset cash_cancel 1
				//if (server_var(check_team) != 3) then es_xmsg #green Cancel: Team
			}
		}
		else do
		{
			//es_xmsg #green Cancel: Interval
			es_xset cash_cancel 1
		}
	}
	else do
	{
		//es_xmsg #green Cancel: 1st Round
		es_xset cash_cancel 1
	}
	if (server_var(cash_cancel) != 1) then es_xdoblock pod_cash/give_cash
}

event round_end
{
	if (event_var(reason) != 15) do
	{
		es_xset cash_1st_played 1
		es_math cash_interval_current + 1
		if (server_var(cash_interval_current) > server_var(cash_interval)) then es_xset cash_interval_current 1
	}
	else do
	{
		es_xset cash_interval_current 1
		if (server_var(cash_first_round) == 1) then es_xset cash_1st_played 0
	}
}

block filter_team
{
	if (server_var(user) != 0) do
	{
		//0 = No Team
		//1 = Spec
		//2 = T
		//3 = CT
		es_xset check_team 0
		es_getplayerteam check_team server_var(user)
	}
}

block filter_bot
{
	//0 = No Bot
	//1 = Bot
	es_xset check_bot 0
	es_isbot check_bot server_var(user)
}

block filter_steam
{
	//0 = Steam not in DB
	//1 = Steam in DB
	es_xset get_steam 0
	es_xset exists 0
	es_xset check_steam 0
	es_getplayersteamid get_steam server_var(user)
	es_exists exists keyvalue pod_cash steam server_var(get_steam)
	if (server_var(exists) == 1) then es_xset check_steam 1
}

block give_cash
{
	es_xset getcash 0
	es playerget cash getcash server_var(user)
	es_math getcash + server_var(cash_amount)
	if (server_var(getcash) > 16000) do
	{
		es playerset cash server_var(user) 16000
	}
	else do
	{
		es playerset cashadd server_var(user) server_var(cash_amount)
	}
	if (server_var(cash_advert) == 1) then es_tell server_var(user) #multi #green[PoD-Cash] #defaultYou received#lightgreen server_var(cash_amount) $
	if (server_var(cash_advert) == 3) then es_tell server_var(user) #multi #green[PoD-Cash] #defaultYou received#lightgreen server_var(cash_amount) $
}